Shader "Custom/Dissolve"
{
	Properties {
		_Color ("Color", Color) = (1,1,1,1)
		_MainTex ("Albedo (RGB)", 2D) = "white" {}
		_Glossiness ("Smoothness", Range(0,1)) = 0.5
		_Metallic ("Metallic", Range(0,1)) = 0.0

		_DissolveTexture("Dissolve Texture", 2D) = "white" {} 
		_Amount("Amount", Range(0,1)) = 0
		_DissolveColor ("Disolve Color", Color) = (1,1,1,1)
		_DissolveColorAlpha ("Dissolve Color Alpha", Range(0,1)) = 0.0
	}
	 
	SubShader {
		Tags { "RenderType"="Opaque" }
		LOD 200
		Cull Off

		CGPROGRAM
		#pragma surface surf Standard fullforwardshadows

		#pragma target 3.0

		sampler2D _MainTex;

		struct Input {
			float2 uv_MainTex;
		};

		half _Glossiness;
		half _Metallic;
		fixed4 _Color;
		fixed3 _DissolveColor;
		half _DissolveColorAlpha;

		//Dissolve properties
		sampler2D _DissolveTexture;
		half _Amount;

		void surf (Input IN, inout SurfaceOutputStandard o) {

			//Dissolve function
			half dissolve_value = tex2D(_DissolveTexture, IN.uv_MainTex).r;
			clip(dissolve_value - _Amount);

			//Basic shader function
			fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color; 

			o.Albedo = c.rgb;
			o.Metallic = _Metallic;
			o.Smoothness = _Glossiness;
			o.Alpha = c.a;
			o.Emission = fixed3(_DissolveColor.r, _DissolveColor.g, _DissolveColor.b) * step( dissolve_value - _Amount, _DissolveColorAlpha); //emits white color with 0.05 border size
		}
		ENDCG
	}
	FallBack "Diffuse"
}